मिकरोटिक राउटर ओएस, गतिशील गति विभाजन की एक स्क्रिप्ट (संस्करण 2)

मिकरोटिक राउटर ओएस, गतिशील गति विभाजन की एक स्क्रिप्ट (संस्करण 2)

यह दूसरा संस्करण है, पहला यहाँ है: यहाँ।



दूसरे दिन, निम्नलिखित समस्या उत्पन्न हुई: गति को सभी उपयोगकर्ताओं के बीच समान रूप से विभाजित करने के लिए, ताकि गति उन ग्राहकों को आवंटित न की जाए जो वर्तमान में इंटरनेट का उपयोग नहीं करते हैं, लेकिन बाकी सभी को दिया गया है, ताकि बड़ी संख्या में ग्राहकों और एक संकीर्ण चैनल के साथ, कुछ "बफरिंग" हो। चैनल।



पिछले अनुभव के आधार पर, अतीत की कमियों को खत्म करने के लिए एक पूरी तरह से नई स्क्रिप्ट लिखी गई थी और वर्तमान जरूरतों के लिए अंतिम रूप दिया गया था।



नए संस्करण में, उपयोगकर्ता स्थान के संदर्भ में यह बहुत आसान हो गया है, अब इससे कोई फर्क नहीं पड़ता कि उपयोगकर्ता कैसे जुड़ा है, मुख्य बात यह है कि उसके पास एक आईपी पता है और हमारे लिए यह पर्याप्त है।



तो चलिए जाने ...

तीन उपयोगकर्ताओं के लिए एक उदाहरण।

उपयोगकर्ता पते 192.168.5.100-192.168.5.102



हम सूचियों में तीन उपयोगकर्ता जोड़ते हैं, और केवल वे जो वास्तव में मौजूद हैं। यदि आप इसका उपयोग नहीं कर रहे हैं, तो आपको पूरी रेंज स्कोर करने की आवश्यकता नहीं है, क्योंकि हर अतिरिक्त रिकॉर्ड प्रदर्शन को बहुत प्रभावित करेगा।



/ip firewall address-list add list="users" address=192.168.5.100

/ip firewall address-list add list="users" address=192.168.5.101

/ip firewall address-list add list="users" address=192.168.5.102









सूचियों को मैन्युअल रूप से नहीं जोड़ने के लिए, एक छोटा सा चक्र फेंका गया था जो श्रेणियों को जोड़ने की प्रक्रिया को गति देगा। इस तरह की स्क्रिप्ट का एक ही रन वही करेगा जो हमने ऊपर किया था।



#Settings

######################################################

:local start ("100");

:local stop ("102");

:local net ("192.168.5.");

######################################################



######################################################

:global count ($start);

:for count from=$start to=$stop step=1 do={

/ip firewall address-list add list="users" address=( $net . $count);};

######################################################



######################################################

# (C) Inlarion icq 429-587 mikrotik.axiom-pro.ru Copyright!

######################################################









दूसरा चरण है, प्रविष्टियों को / कतार और / ip फ़ायरवॉल मैन्ग में जोड़ना, फिर से प्रशासक को प्रविष्टियों को मैन्युअल रूप से जोड़ने की दिनचर्या से मुक्त करना, जो तब से त्रुटियों से भरा है मानव कारक सो नहीं रहा है, एक छोटी सी स्क्रिप्ट को स्केच किया गया है। इस स्क्रिप्ट को हर बार आपके द्वारा / ip फ़ायरवॉल एड्रेस-लिस्ट सूची = "उपयोगकर्ताओं" में प्रविष्टियों को जोड़ने या हटाने की आवश्यकता होती है, इसका मुख्य कार्य नई प्रविष्टियों को जोड़ना और अनावश्यक पुराने को हटाना है, यह स्पष्ट है कि एक सामान्य सिस्टम व्यवस्थापक को कचरा नहीं होना चाहिए, जो हटाना भूल गया। स्क्रिप्ट खत्म होने के बाद, सिस्टम लॉग में जोड़े गए और हटाए गए रिकॉर्ड की संख्या की जानकारी दर्ज की जाएगी।



#Settings

######################################################

:local DownloadParent ("Download");

:local UploadParent ("Upload");

######################################################



#Internal Var

######################################################

:local i;

:local z;

:local userX;

:local enum (" ");

:local mark;

:local qrd;

:local qru;

:local mrd;

:local mru;

:local qrdadd;

:local qruadd;

:local mrdadd;

:local mruadd;

:set qrd (0);

:set qru (0);

:set mrd (0);

:set mru (0);

:set qrdadd (0);

:set qruadd (0);

:set mrdadd (0);

:set mruadd (0);

######################################################



######################################################

:log warning ("Rules Manager Started!");



:if ([/queue type find name="dshaper_down"] = "") do={ /queue type add name="dshaper_down" kind="pcq" pcq-classifier=dst-address pcq-rate=0 pcq-limit=50 pcq-total-limit=2000;};



:if ([/queue type find name="dshaper_up"] = "") do={ /queue type add name="dshaper_up" kind="pcq" pcq-classifier=src-address pcq-rate=0 pcq-limit=50 pcq-total-limit=2000;};



:if ([/queue tree find name=$DownloadParent] = "") do={ /queue tree add name=$DownloadParent parent="global-out" queue="dshaper_down" priority=8;};

:if ([/queue tree find name=$UploadParent] = "") do={ /queue tree add name=$UploadParent parent="global-out" queue="dshaper_up" priority=8;};



:foreach i in=[/ip firewall address-list find list="users"] do={ :set userX [/ip firewall address-list get $i address];



:if ([/queue tree find name=($userX . "_down")] = "") do={ /queue tree add name=($userX . "_down") parent=$DownloadParent queue="dshaper_down" packet-mark=($userX . "_down") priority=8; :set qrdadd ($qrdadd+1); };

:if ([/queue tree find name=($userX . "_up")] = "") do={ /queue tree add name=($userX . "_up") parent=$UploadParent queue="dshaper_up" packet-mark=($userX . "_up") priority=8; :set qruadd ($qruadd+1);};



:set enum (" ");

:set enum ([/ip firewall mangle find comment=($userX . "_up")]);

:if ($enum = "") do={ /ip firewall mangle add chain=forward src-address=$userX dst-address=0.0.0.0/0 action=mark-packet new-packet-mark=($userX . "_up") comment=($userX . "_up") disabled=no passthrough=yes; :set mruadd ($mruadd+1);

};



:set enum (" ");

:set enum ([/ip firewall mangle find comment=($userX . "_down")]);

:if ($enum = "") do={ /ip firewall mangle add chain=forward src-address=0.0.0.0/0 dst-address=$userX action=mark-packet new-packet-mark=($userX . "_down") comment=($userX . "_down") disabled=no passthrough=yes; :set mrdadd ($mrdadd+1);

};



};



:foreach z in=[/queue tree find parent=$DownloadParent] do={

:set mark [/queue tree get $z name];

:if ($mark !="") do={

:set mark ([:tostr $mark]);

:set mark ([:pick $mark 0 ([:len $mark]-5)]);

:if ([/ip firewall address-list find address=$mark] = "") do={/queue tree remove [/queue tree find name=($mark . "_down")]; :set qrd ($qrd+1); };};};



:foreach z in=[/queue tree find parent=$UploadParent] do={

:set mark [/queue tree get $z name];

:if ($mark !="") do={

:set mark ([:tostr $mark]);

:set mark ([:pick $mark 0 ([:len $mark]-3)]);

:if ([/ip firewall address-list find address=$mark] = "") do={/queue tree remove [/queue tree find name=($mark . "_up")]; :set qru ($qru+1); };};};



:foreach z in=[/ip firewall mangle find src-address="0.0.0.0/0" action="mark-packet" chain="forward"] do={

:set mark [/ ip firewall mangle get $z comment];

:if ($mark !="") do={

:set mark ([:tostr $mark]);

:set mark ([:pick $mark 0 ([:len $mark]-5)]);

:if ([/ip firewall address-list find address=$mark] = "") do={

:if ([/ip firewall mangle find comment=($mark . "_down")] != "") do={/ip firewall mangle remove [/ip firewall mangle find comment=($mark . "_down")]; :set mrd ($mrd+1); }}}}



:foreach z in=[/ip firewall mangle find dst-address="0.0.0.0/0" action="mark-packet" chain="forward"] do={

:set mark [/ ip firewall mangle get $z comment];

:if ($mark !="") do={

:set mark ([:tostr $mark]);

:set mark ([:pick $mark 0 ([:len $mark]-3)]);

:if ([/ip firewall address-list find address=$mark] = "") do={

:if ([/ip firewall mangle find comment=($mark . "_up")] != "") do={/ip firewall mangle remove [/ ip firewall mangle find comment=($mark . "_up")]; :set mru ($mru+1); }}}}

######################################################



######################################################

:log info ("------------------------------------------");

:log warning ("Rules Manager:");

:log info ("Queue Tree Download Records Added: " . $qrdadd);

:log info ("Queue Tree Upload Records Added: " . $qruadd);

:log info ("Mangle Download Records Added: " . $mrdadd);

:log info ("Mangle Upload Records Added: " . $mruadd);

:log info ("Queue Tree Download Records Deleted: " . $qrd);

:log info ("Queue Tree Upload Records Deleted: " . $qru);

:log info ("Mangle Download Records Deleted: " . $mrd);

:log info ("Mangle Upload Records Deleted: " . $mru);

:log info ("------------------------------------------");

######################################################



######################################################

# (C) Inlarion icq 429-587 mikrotik.axiom-pro.ru Copyright!

######################################################



अब सर्किट के कम्प्यूटेशनल और कार्यकारी भागों की स्क्रिप्ट

लिपि का सिद्धांत।

स्क्रिप्ट निर्धारित करती है कि क्या रात का समय समर्थन सक्षम है और वर्तमान समय की जांच करता है, समय सीमा के अनुसार चैनल बैंडविड्थ का चयन करता है।

स्क्रिप्ट मापती है कि क्लाइंट कितनी तेजी से काम कर रहा है और यदि वह ActiveThresholddown से अधिक है, तो इसे रिसेप्शन पर एक सक्रिय के रूप में जोड़ा जाता है।

यह सक्रिय ग्राहकों के काउंटर को भी बढ़ाता है।

इसके बाद, यह ActiveThresholdup की जांच करता है, यदि उपयोगकर्ता ने इस चिह्न को पार कर लिया है, तो यह इसे रिटर्न पर सक्रिय के रूप में जोड़ता है।

इसके अलावा, वापसी ग्राहकों पर सक्रिय के काउंटर को बढ़ाता है।



गणना करता है:

MaxRateDownload प्राप्त करने के लिए सक्रिय उपयोगकर्ताओं की संख्या से विभाजित करता है, प्रति उपयोगकर्ता गति प्रदर्शित करता है।

MaxRateUpload प्रति उपयोगकर्ता सक्रिय उपयोगकर्ताओं की संख्या से विभाजित होता है, प्रति उपयोगकर्ता गति प्रदर्शित करता है।



इसके बाद, यह ऊपर की गणना की गई योजना के अनुसार क्यू ट्री में सभी उपयोगकर्ताओं के लिए एक सीमा निर्धारित करता है।



फिर यह किलोबाइट में मूल्य की गणना करता है और लॉग में आंकड़े प्रदर्शित करता है।

बहुत शुरुआत में स्क्रिप्ट में चर:

MaxRateDownload - सभी उपयोगकर्ताओं (स्वागत) बिट / सेकंड के लिए चैनल की चौड़ाई।

MaxRateUpload - सभी उपयोगकर्ताओं के लिए चैनल की चौड़ाई (वापसी) बिट / सेकंड।

MaxRateDownloadNight - रात (रिसेप्शन) बिट / सेकंड में सभी उपयोगकर्ताओं के लिए चैनल की चौड़ाई।

MaxRateUploadNight - रात (वापसी) बिट / सेकंड में सभी उपयोगकर्ताओं के लिए चैनल की चौड़ाई।



ActiveThresholddown - अधिक होने पर थ्रेशोल्ड, जो उपयोगकर्ता को सक्रिय माना जाएगा (रिसेप्शन) Bit / s।

ActiveThresholdup - अधिक होने पर थ्रेशोल्ड, जिसे उपयोगकर्ता सक्रिय (वापसी) बिट / सेकंड माना जाएगा।



usenighttime - "हाँ" और "नहीं" मानों को स्वीकार कर सकता है, स्क्रिप्ट को एक अलग चैनल चौड़ाई का उपयोग करने की अनुमति देता है। रात्रि दर के अनुसार।

नाइटटीमस्टार्ट-स्क्रिप्ट को रात के टैरिफ की शुरुआत की सूचना देता है।

नाइटटीमस्टॉप-स्क्रिप्ट को रात के टैरिफ के अंत की सूचना देता है।



#Settings

######################################################

:local MaxRateDownload ("15000000");

:local MaxRateUpload ("15000000");

:local MaxRateDownloadNight ("20000000");

:local MaxRateUploadNight ("20000000");



:local ActiveThresholddown ("15000");

:local ActiveThresholdup ("15000");



:local usenighttime ("yes");

:local nighttimestart ("02:00");

:local nighttimestop ("08:00");

######################################################



#Internal Var

######################################################

:local z;

:local i;

:local ii;

:local userX;

:local timedelay (0);

:local startmin;

:local startsec;

:local stopmin;

:local stopsec;

:local scripttimedelay (0);

:local scriptstartmin;

:local scriptstartsec;

:local scriptstopmin;

:local scriptstopsec;

:local userscount ("0");

:local userstmp ("");

:local firstdowntmp ("");

:local firstuptmp ("");

:local twodowntmp ("");

:local twouptmp ("");

:local activedownuserstmp ("");

:local activeupuserstmp ("");

:local activedowncount ("0");

:local activeupcount ("0");

######################################################



######################################################

:set scriptstartmin ([: pick [/system clock get time] 3 5]);

:set scriptstartsec ([: pick [/system clock get time] 6 8]);



:if ($usenighttime = "yes") do={

:set nighttimestart ([: pick $nighttimestart 0 2] . [: pick $nighttimestart 3 5]);

:set nighttimestop ([: pick $nighttimestop 0 2] . [: pick $nighttimestop 3 5]);

:local currenthours ([: pick [/system clock get time] 0 2]);

:local currenttime ([: pick [/system clock get time] 0 2] . [: pick [/system clock get time] 3 5] );

:local acttime ("day");

:local starttime ("day");

:if ($currenthours < 10) do={ :set acttime ("night"); };

:if ( [: pick $nighttimestart 0 2] < 10) do={ :set starttime ("night"); };

:local night ("no");



:if ($starttime = "night") do={

:if ( $currenttime > $nighttimestart && $currenttime < $nighttimestop) do={ :set night ("yes"); };

};

:if ($starttime = "day") do={

:if ( $acttime = "day") do={

:if ( $currenttime >= $nighttimestart) do={ :set night ("yes"); };

};

:if ( $acttime = "night") do={

:if ( $currenttime < $nighttimestop ) do={ :set night ("yes"); };

};};



:if ($night = "yes") do={

:set MaxRateDownload ($MaxRateDownloadNight);

:set MaxRateUpload ($MaxRateUploadNight);

};

};



:set ActiveThresholddown ($ActiveThresholddown / 8);

:set ActiveThresholdup ($ActiveThresholdup / 8);



:foreach i in=[/ip firewall address-list find list="users"] do={ :set userX [/ip firewall address-list get $i address];

:set userscount ($userscount+1);

:set userstmp ($userstmp . $userX . ",");

};



:local users [:toarray $userstmp];



:set startmin ([: pick [/system clock get time] 3 5]);

:set startsec ([: pick [/system clock get time] 6 8]);



:global dcount ("1");

:for dcount from=1 to=$userscount step=1 do={

:set firstdowntmp ($firstdowntmp . [/ip firewall mangle get [/ip firewall mangle find comment=[:pick $users ($dcount-1)] . "_down"] bytes] . ",");

:set firstuptmp ($firstuptmp . [/ip firewall mangle get [/ip firewall mangle find comment=[:pick $users ($dcount-1)] . "_up"] bytes] . ",");

};



:set stopmin ([: pick [/system clock get time] 3 5]);

:set stopsec ([: pick [/system clock get time] 6 8]);



:global dcount ("1");

:for dcount from=1 to=$userscount step=1 do={

:set twodowntmp ($twodowntmp . [/ip firewall mangle get [/ip firewall mangle find comment=[:pick $users ($dcount-1)] . "_down"] bytes] . ",");

:set twouptmp ($twouptmp . [/ip firewall mangle get [/ip firewall mangle find comment=[:pick $users ($dcount-1)] . "_up"] bytes] . ",");

};



:if ( $stopmin > $startmin) do={

:set timedelay (($stopmin-$startmin) * 60);

};

:set timedelay (($timedelay+$stopsec)-$startsec);



:local firstdown [:toarray $firstdowntmp];

:local firstup [:toarray $firstuptmp];

:local twodown [:toarray $twodowntmp];

:local twoup [:toarray $twouptmp];



:global dcount ("1");

:for dcount from=1 to=$userscount step=1 do={



:if ( ($ActiveThresholddown * $timedelay) < ([:pick $twodown ($dcount-1)] - [:pick $firstdown ($dcount-1)]) ) do={

:set activedownuserstmp ($activedownuserstmp . [:pick $users ($dcount-1)] . ",");

:set activedowncount ($activedowncount+1);

};



:if ( ($ActiveThresholdup * $timedelay) < ([:pick $twoup ($dcount-1)] - [:pick $firstup ($dcount-1)]) ) do={

:set activeupuserstmp ($activeupuserstmp . [:pick $users ($dcount-1)] . ",");

:set activeupcount ($activeupcount+1);

};



};



:local activedownusers [:toarray $activedownuserstmp];

:local activeupusers [:toarray $activeupuserstmp];



:local maxlimitdown ("0");

:local maxlimitup ("0");



:if ( $activedowncount > 0 ) do={

:set maxlimitdown ($MaxRateDownload/$activedowncount);

:global dcount ("1");

:for dcount from=1 to=$activedowncount step=1 do={

:if ([/queue tree get [find name=[:pick $activedownusers ($dcount-1)] . "_down"] max-limit] != $maxlimitdown) do={

/queue tree set [/queue tree find name=[:pick $activedownusers ($dcount-1)] . "_down"] max-limit=$maxlimitdown; };

};

};



:if ( $activeupcount > 0 ) do={

:set maxlimitup ($MaxRateUpload/$activeupcount);

:global dcount ("1");

:for dcount from=1 to=$activeupcount step=1 do={

:if ([/queue tree get [find name=[:pick $activeupusers ($dcount-1)] . "_up"] max-limit] != $maxlimitup) do={

/queue tree set [/queue tree find name=[:pick $activeupusers ($dcount-1)] . "_up"] max-limit=$maxlimitup; };

};

};



:local kbsmaxdown ($MaxRateDownload/1000);

:local kbsmaxup ($MaxRateUpload /1000);



:if ( $maxlimitdown = 0 ) do={ :set maxlimitdown ($MaxRateDownload); };

:if ( $maxlimitup = 0 ) do={ :set maxlimitup ($MaxRateUpload); };

:local kbsmaxlimitdown ($maxlimitdown/1024);

:local kbsmaxlimitup ($maxlimitup/1024);



:set scriptstopmin ([: pick [/system clock get time] 3 5]);

:set scriptstopsec ([: pick [/system clock get time] 6 8]);



:if ( $scriptstopmin > $scriptstartmin) do={

:set scripttimedelay (($scriptstopmin-$scriptstartmin) * 60);

};

:set scripttimedelay (($scripttimedelay+$scriptstopsec)-$scriptstartsec);

######################################################



######################################################

:log info ("------------------------------------------");

:log warning ("Shaper:");

:log info ("MaxRate Download : " . $MaxRateDownload . " bps /" . $kbsmaxdown . " kbs / Upload : " . $MaxRateUpload . " bps /" . $kbsmaxup . " kbs");

:log info ("Active Users : Download : " . $activedowncount . " / Upload : " . $activeupcount );

:log info ("User Speed Download : " . $maxlimitdown . " bps /" . $kbsmaxlimitdown . " kbs / Upload : " . $maxlimitdown . " bps /" . $kbsmaxlimitup . " kbs" );

:log warning ("Performance Time: " . $scripttimedelay . " seconds.");

:log info ("------------------------------------------");

######################################################



######################################################

# (C) Inlarion icq 429-587 mikrotik.axiom-pro.ru Copyright!

######################################################



नवीनतम इच्छाओं के बारे में

इस संस्करण में, आप प्रदर्शन टाइम सिस्टम लॉग में एक नई लाइन को जोड़ने का नोटिस कर सकते हैं, यह लाइन आपको शेड्यूलर में स्क्रिप्ट निष्पादन अंतराल को सही ढंग से सेट करने की अनुमति देती है। "प्रदर्शन समय" सेकंड की स्क्रिप्ट का निष्पादन समय + -1 सेकंड की सटीकता के साथ दर्शाता है। इस समय के साथ / ip फ़ायरवॉल एड्रेस-लिस्ट सूची में जोड़े गए ग्राहकों की संख्या में तेजी से वृद्धि होती है = "उपयोगकर्ता", आपके माइक्रोटिक पर लोड और स्क्रिप्ट निष्पादन अंतराल गलत तरीके से सेट होता है, इसलिए इस पैरामीटर की लगातार निगरानी की जानी चाहिए।



सूत्र के आधार पर स्क्रिप्ट निष्पादन अंतराल सेट करें: प्रदर्शन समय + 10-15 सेकंड। जब आप पहली बार स्क्रिप्ट चलाते हैं, तो अंतराल को 1-2 मिनट के लिए सेट करें, आदर्श रूप से यदि सिस्टम उस समय यथासंभव व्यस्त है।

स्क्रिप्ट पैरामीटर:

:local MaxRateDownload ("15000000");

:local MaxRateUpload ("15000000");

:local MaxRateDownloadNight ("20000000");

:local MaxRateUploadNight ("20000000");







आपको अपने चैनल की चौड़ाई से थोड़ा कम सेट करना चाहिए ताकि ब्रेक से बचने के लिए जब कोई अन्य उपयोगकर्ता जो पहले इंटरनेट का उपभोग नहीं करता है, सक्रिय हो।



:local ActiveThresholddown ("15000");

:local ActiveThresholdup ("15000");









अपनी आवश्यकताओं के अनुसार इन मूल्यों को सेट करें, लेकिन गणना के आधार पर: थ्रेसहोल्डडाउन द्वारा गुणा किए जाने वाले उपयोगकर्ताओं की संख्या = मैक्सरेडडाउनलोड से अधिक नहीं होनी चाहिए अन्यथा आपके उपयोगकर्ता हमेशा निष्क्रिय रहेंगे! स्वाभाविक रूप से उपयोगकर्ता * ActiveThresholdup = MaxRateUpload से अधिक नहीं होना चाहिए। हमेशा कुछ मार्जिन छोड़ दें।



सब कुछ के अलावा, मैं यह नोट करना चाहता हूं कि संस्करण 5.x में स्क्रिप्ट का उपयोग करने की अनुपयुक्तता का सवाल बंद है, क्योंकि संस्करण 5.0rc7 के परीक्षण के बाद, मैं वास्तव में आश्वस्त हो गया कि मिकरोटिक में कतार पहले के संस्करणों की तुलना में बहुत बेहतर काम करने लगी है, इसलिए संस्करण 5.x में स्क्रिप्ट की आवश्यकता नहीं है। लेकिन डेवलपर्स को अनुमति देने वाले बग को देखते हुए पांचवें संस्करण में स्विच करने का मुद्दा बहुत ही संदिग्ध है। उदाहरण के लिए, आरसी 3 में, पिंग उपयोगिता अनाड़ी है और मापदंडों को वापस नहीं करता है, आरसी 7 में, तालिका में नामों का उपयोग करते समय राउटिंग काम नहीं करता है, हालांकि पहले के संस्करणों में सब कुछ एक धमाके के साथ काम करता था। लेकिन यह सिर्फ आरसी है, हालांकि यह पहले से ही सातवीं पंक्ति में है और यह बहुत चिंताजनक है।



भले ही आपको मुख्य भाग की आवश्यकता नहीं है, लेकिन आप / कतार पेड़ का उपयोग करते हैं, आप बस नियमों को बनाने के लिए स्क्रिप्ट का उपयोग कर सकते हैं, उपयोगकर्ताओं को जोड़ते / निकालते समय एक बहुत ही सुविधाजनक चीज।